src/ledger/bin/p2p_sync/impl/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//third_party/flatbuffers/flatbuffer.gni")

visibility = [ "//src/ledger/*" ]

source_set("impl") {
  sources = [
    "commit_batch.cc",
    "commit_batch.h",
    "device_mesh.h",
    "flatbuffer_message_factory.cc",
    "flatbuffer_message_factory.h",
    "ledger_communicator_impl.cc",
    "ledger_communicator_impl.h",
    "message_holder.h",
    "page_communicator_impl.cc",
    "page_communicator_impl.h",
    "user_communicator_factory_impl.cc",
    "user_communicator_factory_impl.h",
    "user_communicator_impl.cc",
    "user_communicator_impl.h",
  ]

  public_deps = [
    "//peridot/lib/convert",
    "//sdk/fidl/fuchsia.modular.auth",
    "//src/ledger/bin/environment",
    "//src/ledger/bin/p2p_provider/impl",
    "//src/ledger/bin/p2p_sync/public",
    "//src/ledger/bin/storage/public",
    "//src/lib/fxl",
  ]

  deps = [
    ":message",
    "//garnet/public/lib/callback",
    "//peridot/lib/ledger_client:constants",
  ]
}

flatbuffer("message") {
  sources = [
    "message.fbs",
  ]
}

source_set("unittests") {
  testonly = true

  sources = [
    "page_communicator_impl_unittest.cc",
    "user_communicator_impl_unittest.cc",
  ]

  deps = [
    ":impl",
    "//garnet/public/lib/fsl",
    "//sdk/lib/fidl/cpp",
    "//src/ledger/bin/p2p_provider/impl",
    "//src/ledger/bin/storage/fake:lib",
    "//src/ledger/bin/storage/testing",
    "//src/ledger/bin/testing:lib",
    "//src/ledger/bin/testing/netconnector",
    "//src/lib/fxl",

    # gtest matchers are in gmock.
    "//third_party/googletest:gmock",
    "//third_party/googletest:gtest",
  ]

  configs += [ "//src/ledger:ledger_config" ]
}