| # Copyright 2016 The Fuchsia Authors. All rights reserved. |
| # Use of this source code is governed by a BSD-style license that can be |
| # found in the LICENSE file. |
| |
| import("//build/fuzzing/fuzzer.gni") |
| import("//build/package.gni") |
| |
| visibility = [ "//src/ledger/*" ] |
| |
| package("bin") { |
| package_name = "ledger" |
| |
| deps = [ |
| "app", |
| "cobalt:ledger_metrics_registry", |
| ] |
| |
| binary = "ledger" |
| |
| meta = [ |
| { |
| path = rebase_path("meta/ledger.cmx") |
| dest = "ledger.cmx" |
| }, |
| ] |
| |
| resources = [ |
| { |
| path = rebase_path( |
| get_label_info("cobalt:ledger_metrics_registry", |
| "target_gen_dir") + "/ledger_metrics_registry.pb") |
| dest = "ledger_cobalt_config.pb" |
| }, |
| { |
| path = rebase_path( |
| get_label_info("cobalt:ledger_metrics_registry", |
| "target_gen_dir") + "/ledger_metrics_registry.pb") |
| dest = "firebase_auth_cobalt_config.pb" |
| }, |
| ] |
| } |
| |
| executable("ledger_unittests") { |
| testonly = true |
| |
| deps = [ |
| "//src/ledger/bin/app:unittests", |
| "//src/ledger/bin/cache:unittests", |
| "//src/ledger/bin/cloud_sync/impl:unittests", |
| "//src/ledger/bin/encryption/impl:unittests", |
| "//src/ledger/bin/encryption/primitives:unittests", |
| "//src/ledger/bin/environment:unittests", |
| "//src/ledger/bin/fidl/error_notifier:unittests", |
| "//src/ledger/bin/filesystem:unittests", |
| "//src/ledger/bin/lock:unittests", |
| "//src/ledger/bin/p2p_provider/impl:unittests", |
| "//src/ledger/bin/p2p_sync/impl:unittests", |
| "//src/ledger/bin/storage/impl:unittests", |
| "//src/ledger/bin/storage/impl/btree:unittests", |
| "//src/ledger/bin/storage/public:unittests", |
| "//src/ledger/bin/storage/testing:unittests", |
| "//src/ledger/bin/sync_coordinator/impl:unittests", |
| "//src/ledger/bin/sync_helper:unittests", |
| "//src/ledger/bin/testing:unittests", |
| "//src/ledger/bin/testing/netconnector:unittests", |
| "//src/lib/fxl:printers", |
| "//third_party/googletest:gtest_main", |
| ] |
| |
| configs += [ "//src/ledger:ledger_config" ] |
| } |
| |
| fuzz_package("ledger_fuzzers") { |
| targets = [ "//src/ledger/bin/storage/impl/btree:encoding_fuzzer" ] |
| sanitizers = [ |
| "asan", |
| "ubsan", |
| ] |
| } |