src/devices/power/drivers/power/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

group("tests") {
  testonly = true
  deps = [
    ":power-bind_test",
    ":power-test",
  ]
}

driver_bind_rules("power-bind") {
  rules = "power.bind"
  bind_output = "power.bindbc"
  tests = "bind-tests.json"
  deps = [
    "//src/devices/bind/fuchsia.platform",
    "//src/devices/bind/fuchsia.power",
  ]
}

fuchsia_driver("power-driver") {
  output_name = "power"
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  sources = [ "power.cc" ]
  deps = [
    ":power-bind",
    "//sdk/banjo/fuchsia.hardware.powerimpl:fuchsia.hardware.powerimpl_banjo_cpp",
    "//sdk/fidl/fuchsia.hardware.power:fuchsia.hardware.power_cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//src/devices/bin/driver_runtime",
    "//src/devices/bind/fuchsia.power:fuchsia.power_cpp",
    "//src/devices/lib/driver",
    "//src/lib/ddk",
    "//src/lib/ddk:ddk-metadata-headers",
    "//src/lib/ddktl",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/zx",
  ]
}

fuchsia_driver_component("power") {
  visibility = [ ":*" ]
  info = "power-info.json"
  component_name = "power"
  deps = [ ":power-driver" ]
  manifest = "meta/power.cml"
}

fuchsia_driver_package("package") {
  package_name = "power"
  driver_components = [ ":power" ]
}

test("power-test-bin") {
  output_name = "generic-power-driver-test"
  sources = [
    "power-test.cc",
    "power.cc",
  ]
  deps = [
    "//sdk/banjo/fuchsia.hardware.powerimpl:fuchsia.hardware.powerimpl_banjo_cpp",
    "//sdk/fidl/fuchsia.hardware.power:fuchsia.hardware.power_cpp",
    "//sdk/lib/async_patterns/testing/cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//sdk/lib/driver/runtime/testing/cpp",
    "//src/devices/bin/driver_runtime",
    "//src/devices/bind/fuchsia.power:fuchsia.power_cpp",
    "//src/devices/testing/mock-ddk",
    "//src/lib/ddk",
    "//src/lib/ddk:ddk-metadata-headers",
    "//src/lib/ddktl",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/zircon-internal",
    "//zircon/system/ulib/zx",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_package("power-test") {
  deps = [ ":power-test-bin" ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}