src/sys/pkg/tests/pkg-local-mirror/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//build/rust/rustc_test.gni")
import("//build/test/test_package.gni")
import("//build/testing/environments.gni")

rustc_test("driver") {
  name = "pkg_local_mirror_integration_test"
  edition = "2018"

  deps = [
    "//garnet/lib/rust/io_util",
    "//sdk/fidl/fuchsia.io:fuchsia.io-rustc",
    "//sdk/fidl/fuchsia.logger:fuchsia.logger-rustc",
    "//sdk/fidl/fuchsia.pkg:fuchsia.pkg-rustc",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-url",
    "//src/lib/storage/vfs/rust:vfs",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//src/sys/lib/fidl-fuchsia-pkg-ext",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:matches",
  ]

  sources = [
    "src/get_blob.rs",
    "src/get_metadata.rs",
    "src/lib.rs",
  ]
}

test_package("pkg-local-mirror-integration-tests") {
  deps = [
    ":driver",
    "//src/sys/pkg/bin/pkg-local-mirror:bin",
  ]

  binaries = [
    {
      name = "pkg-local-mirror"
      source = "pkg_local_mirror"
    },
  ]

  meta = [
    {
      path = rebase_path(
              "//src/sys/pkg/bin/pkg-local-mirror/meta/pkg-local-mirror.cmx")
      dest = "pkg-local-mirror.cmx"
    },
  ]

  tests = [
    {
      name = "pkg_local_mirror_integration_test"
      dest = "pkg-local-mirror-integration-test"
      environments = basic_envs
    },
  ]
}

group("tests") {
  testonly = true
  public_deps = [ ":pkg-local-mirror-integration-tests" ]
}