src/ui/examples/flatland-view-provider/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")

rustc_binary("bin") {
  output_name = "flatland_view_provider"
  with_unit_tests = true
  version = "0.1.0"
  edition = "2021"
  source_root = "src/main.rs"
  sources = [
    "src/internal_message.rs",
    "src/main.rs",
    "src/mouse.rs",
    "src/touch.rs",
  ]

  deps = [
    "//sdk/fidl/fuchsia.math:fuchsia.math-rustc",
    "//sdk/fidl/fuchsia.scenic.scheduling:fuchsia.scenic.scheduling-rustc",
    "//sdk/fidl/fuchsia.sysmem:fuchsia.sysmem-rustc",
    "//sdk/fidl/fuchsia.ui.app:fuchsia.ui.app-rustc",
    "//sdk/fidl/fuchsia.ui.composition:fuchsia.ui.composition-rustc",
    "//sdk/fidl/fuchsia.ui.pointer:fuchsia.ui.pointer-rustc",
    "//sdk/fidl/fuchsia.ui.views:fuchsia.ui.views-rustc",
    "//src/lib/async-utils",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/mapped-vmo",
    "//src/lib/syslog/rust:syslog",
    "//src/lib/trace/rust:trace",
    "//src/lib/trace/rust:trace-provider",
    "//src/lib/ui/flatland-frame-scheduling:flatland-frame-scheduling-lib",
    "//src/lib/ui/fuchsia-framebuffer",
    "//src/lib/ui/fuchsia-scenic",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:log",
  ]
}

fuchsia_component("flatland-view-provider-v1") {
  component_name = "flatland-view-provider-example"
  manifest = "meta/flatland-view-provider-example.cmx"
  deps = [ ":bin" ]
}

fuchsia_component("flatland-view-provider") {
  component_name = "flatland-view-provider"
  manifest = "meta/flatland-view-provider.cml"
  deps = [ ":bin" ]
}

fuchsia_unittest_package("flatland-view-provider-tests") {
  manifest = "meta/flatland-view-provider-tests.cml"
  deps = [ ":bin_test" ]
}