src/ui/tests/integration_input_tests/mouse/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/config.gni")
import("//build/flutter/config.gni")

group("tests") {
  testonly = true
  deps = [
    ":mouse-input-test",
    "//src/chromium:web_engine",
    "//src/cobalt/bin/testing/mock_cobalt",
    "//src/graphics/bin/vulkan_loader",
    "//src/testing/fidl/intl_property_manager",
  ]
}

fidl("test.mouse") {
  sdk_category = "internal"
  sources = [ "response_listener.test.fidl" ]
  public_deps = [ "//zircon/vdso/zx" ]
}

executable("mouse-input-test-bin") {
  testonly = true
  sources = [ "mouse-input-test.cc" ]
  output_name = "mouse-input-test"
  deps = [
    ":test.mouse",
    "//sdk/fidl/fuchsia.accessibility.semantics",
    "//sdk/fidl/fuchsia.buildinfo",
    "//sdk/fidl/fuchsia.cobalt",
    "//sdk/fidl/fuchsia.component",
    "//sdk/fidl/fuchsia.fonts",
    "//sdk/fidl/fuchsia.kernel",
    "//sdk/fidl/fuchsia.memorypressure",
    "//sdk/fidl/fuchsia.net.interfaces",
    "//sdk/fidl/fuchsia.netstack",
    "//sdk/fidl/fuchsia.posix.socket",
    "//sdk/fidl/fuchsia.scheduler",
    "//sdk/fidl/fuchsia.session.scene",
    "//sdk/fidl/fuchsia.sys",
    "//sdk/fidl/fuchsia.tracing.provider",
    "//sdk/fidl/fuchsia.ui.app",
    "//sdk/fidl/fuchsia.ui.input",
    "//sdk/fidl/fuchsia.ui.scenic",
    "//sdk/fidl/fuchsia.vulkan.loader",
    "//sdk/fidl/fuchsia.web",
    "//sdk/lib/sys/component/cpp/testing:cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:integration_fixture",
    "//sdk/lib/ui/scenic/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/lib/ui/input-synthesis:test.inputsynthesis",
    "//src/ui/testing/ui_test_manager",
    "//third_party/googletest:gtest",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/zx",
  ]

  configs += [
    # Allow passing the test even on configs where there is no modern injection.
    "//src/lib/ui/input-synthesis:use_modern_input_injection",
  ]
}

fuchsia_component("mouse-input-test-component") {
  testonly = true
  component_name = "mouse_input_test"
  manifest = "meta/mouse-input-test.cml"
  deps = [ ":mouse-input-test-bin" ]
}

fuchsia_test_package("mouse-input-test") {
  test_components = [ ":mouse-input-test-component" ]
  deps = [
    "mouse-input-chromium:mouse-input-chromium-component",
    "mouse-input-flutter:realm",
    "//src/chromium:web_engine",
    "//src/cobalt/bin/testing/mock_cobalt",
    "//src/connectivity/network/netstack:component",
    "//src/developer/build_info/testing:fake-build-info-component",
    "//src/developer/memory/monitor:component",
    "//src/lib/ui/input-synthesis:input-synthesis-component",
  ]
  test_specs = {
    # Do not fail the test if a message with level ERROR is logged.  Several
    # components will log ERROR if they miss a non-essential FIDL API in the
    # sandbox, which would make the test fail if it weren't for this. For
    # example, the flutter runner is noisy like this. Ideally, we should have
    # a setup that does not have such errors at all, but adding ever more
    # components to satisfy all FIDL dependencies expands the test graph
    # beyond what is practical for testing.  In the future we may strike a
    # balance such that this becomes a non-issue, and that this could be
    # removed.
    log_settings = {
      max_severity = "ERROR"
    }
    environments = [
      {
        dimensions = {
          # Ensure the device has Vulkan.
          device_type = "AEMU"
        }
      },
    ]
  }
}