src/devices/i2c/lib/device-protocol-i2c-channel/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/unification/zx_library.gni")
import("//src/sys/build/fuchsia_unittest_package.gni")

zx_library("device-protocol-i2c-channel") {
  sdk = "source"
  sdk_headers = [ "lib/device-protocol/i2c-channel.h" ]
  sources = []
  public_deps = [
    "//sdk/banjo/ddk.protocol.composite",

    # <lib/device-protocol-i2c-channel/i2c-channel.h> has #include <ddktl/protocol/i2c.h>
    "//sdk/banjo/ddk.protocol.i2c",

    # <lib/device-protocol-i2c-channel/i2c-channel.h> include <lib/device-protocol/i2c.h>
    "//src/devices/i2c/lib/device-protocol-i2c",

    # <lib/device-protocol-i2c-channel/i2c-channel.h> has #include <zircon/types.h>
    "//zircon/public/lib/zx",
  ]
  deps = [
    "//src/devices/i2c/lib/device-protocol-i2c",
    "//zircon/public/lib/zx",
  ]
}

executable("i2c-channel-test-bin") {
  testonly = true
  output_name = "i2c-channel-test"
  sources = [ "test.cc" ]
  deps = [
    "//src/devices/i2c/lib/device-protocol-i2c",
    "//src/devices/i2c/lib/device-protocol-i2c-channel",
    "//src/devices/i2c/testing/fake-i2c",
    "//zircon/public/lib/zxtest",
  ]
}

fuchsia_unittest_package("i2c-channel-test") {
  executable_path = "bin/i2c-channel-test"
  deps = [ ":i2c-channel-test-bin" ]
}

group("tests") {
  testonly = true
  deps = [ ":i2c-channel-test" ]
}