sdk/cts/build/fidl/cts_fidl.gni

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/fidl/fidl.gni")
import("//sdk/cts/build/cts_element.gni")
import("//sdk/cts/build/write_cts_file.gni")

# Declares a FIDL Library that can be used in CTS.
#
# An equivalent to fidl.gni, but ensures deendencies are allowed in CTS.
template("cts_fidl") {
  assert(defined(invoker.sources), "Sources must be defined.")
  assert(!defined(invoker.deps), "All FIDL dependencies should be public.")

  if (defined(invoker.public_deps) && invoker.public_deps != []) {
    cts_element("${target_name}_verify_deps") {
      deps = invoker.public_deps
      invoker_label = get_label_info(invoker.target_name, "label_no_toolchain")
    }
  }

  fidl(target_name) {
    forward_variables_from(invoker, "*")
    if (defined(public_deps) && public_deps != []) {
      public_deps += [ ":${target_name}_verify_deps" ]
    }
  }

  write_cts_file(target_name) {
  }
}