src/ui/bin/root_presenter/tests/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/testing/environments.gni")
import("//src/sys/build/components.gni")

group("tests") {
  testonly = true
  public_deps = [
    ":focus_dispatcher_unittests",
    ":root_presenter_tests",
  ]
}

fuchsia_component("focus_dispatcher_unittests") {
  testonly = true
  deps = [ ":focus_dispatcher_unittests_bin" ]
  manifest = "meta/focus_dispatcher_unittests.cmx"
}

fuchsia_component("root_presenter_apptests") {
  testonly = true
  deps = [ ":root_presenter_apptests_bin" ]
  manifest = "meta/root_presenter_apptests.cmx"
}

fuchsia_unittest_component("root_presenter_unittests") {
  deps = [ ":root_presenter_unittests_bin" ]
  manifest = "meta/root_presenter_unittests.cmx"
}

fuchsia_test_package("root_presenter_tests") {
  test_components = [
    ":root_presenter_apptests",
    ":root_presenter_unittests",
    ":focus_dispatcher_unittests",
  ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
    environments = [ nuc_env ]
  }
}

executable("root_presenter_unittests_bin") {
  testonly = true
  output_name = "root_presenter_unittests"

  sources = [
    "color_transform_handler_unittest.cc",
    "display_configuration_unittest.cc",
    "factory_reset_manager_test.cc",
    "media_buttons_handler_unittest.cc",
    "root_presenter_unittest.cc",
    "safe_presenter_unittest.cc",
  ]

  deps = [
    "//garnet/public/lib/gtest",
    "//sdk/fidl/fuchsia.accessibility",
    "//sdk/fidl/fuchsia.media.sounds",
    "//sdk/fidl/fuchsia.recovery",
    "//sdk/fidl/fuchsia.recovery.policy",
    "//sdk/fidl/fuchsia.sys",
    "//sdk/fidl/fuchsia.ui.brightness",
    "//sdk/fidl/fuchsia.ui.focus",
    "//sdk/fidl/fuchsia.ui.input",
    "//sdk/fidl/fuchsia.ui.policy",
    "//sdk/fidl/fuchsia.ui.scenic",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:unit",
    "//sdk/lib/ui/scenic/cpp",
    "//src/lib/fxl",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/ui/bin/root_presenter:color_transform",
    "//src/ui/bin/root_presenter:displays",
    "//src/ui/bin/root_presenter:factory_reset_manager",
    "//src/ui/bin/root_presenter:lib",
    "//src/ui/bin/root_presenter:media_buttons_handler",
    "//src/ui/bin/root_presenter:safe_presenter",
    "//src/ui/bin/root_presenter/tests/fakes",
    "//src/ui/lib/key_util",
    "//src/ui/testing:mock_input_device",
    "//third_party/googletest:gmock",
  ]
}

executable("root_presenter_apptests_bin") {
  testonly = true
  output_name = "root_presenter_apptests"

  sources = [
    "accessibility_focuser_registry_test.cc",
    "accessibility_pointer_event_registry_test.cc",
  ]

  deps = [
    "//garnet/public/lib/gtest",
    "//sdk/fidl/fuchsia.ui.input.accessibility",
    "//sdk/fidl/fuchsia.ui.policy.accessibility",
    "//sdk/lib/fidl/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:integration",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/ui/bin/root_presenter:lib",
    "//src/ui/bin/root_presenter/tests/fakes",
  ]
}

executable("focus_dispatcher_unittests_bin") {
  testonly = true
  output_name = "focus_dispatcher_unittests"

  sources = [ "focus_dispatcher_unittest.cc" ]

  deps = [
    "//garnet/public/lib/gtest",
    "//sdk/fidl/fuchsia.ui.input.accessibility",
    "//sdk/fidl/fuchsia.ui.policy.accessibility",
    "//sdk/lib/fidl/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:integration",
    "//sdk/lib/sys/cpp/testing:unit",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/ui/bin/root_presenter:lib",
    "//src/ui/bin/root_presenter/tests/fakes",
  ]
}