src/devices/tests/bind-debugger-test/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/config/fuchsia/rules.gni")
import("//build/test.gni")
import("//zircon/system/ulib/devmgr-integration-test/isolated_devmgr.gni")

test("test") {
  output_name = "bind-debugger-test"

  sources = [ "bind-debugger-test.cc" ]

  deps = [
    "//sdk/fidl/fuchsia.device:fuchsia.device_llcpp",
    "//sdk/fidl/fuchsia.device.manager",
    "//sdk/fidl/fuchsia.device.test:fuchsia.device.test_llcpp",
    "//sdk/lib/fdio",
    "//sdk/lib/sys/cpp",
    "//src/lib/ddk",
    "//src/lib/fxl",
    "//src/lib/fxl/test:gtest_main",
    "//zircon/system/ulib/devmgr-integration-test",

    # TODO(fxb/38132): Migrate to the new bind rules and delete the below
    "//src/lib/ddk:ddk-deprecated-binding-headers",
  ]
}

isolated_devmgr_unittest_package("bind-debugger-test") {
  executable_path = "test/bind-debugger-test"

  deps = [
    ":bind-debugger-test-driver",
    ":test",
    "//src/devices/misc/drivers/test",
    "//src/devices/tests/sysdev",
  ]
}

bind_rules("bind") {
  rules = "bind-debugger-test.bind"
  output = "bind-debugger-test-bind.h"
  disable_autobind = true
  deps = [ "//src/devices/bind/fuchsia.test" ]
}

driver_module("bind-debugger-test-driver") {
  output_name = "bind-debugger-test"
  test = true
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  if (is_fuchsia) {
    configs += [ "//build/unification/config:zircon-migrated" ]
  }
  sources = [ "bind-debugger-test-driver.cc" ]
  deps = [
    ":bind",
    "//src/devices/lib/driver",
    "//src/lib/ddk",
  ]
}