blob: 37f939a94f98e097f0ab673e0321cfc5cbc8a0a3 [file]
# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
import("//build/drivers.gni")
config("codec_impl_include_config") {
# TODO(b/525150193): Stop doing #include <lib/media/codec_impl/fourcc.h>, to
# allow using bazel2gn. Instead clients will include
# src/media/lib/codec_impl/fourcc.h, for example.
include_dirs = [ "include" ]
}
source_set("fourcc") {
public_configs = [ ":codec_impl_include_config" ]
public = [ "include/lib/media/codec_impl/fourcc.h" ]
}
config("codec_impl_no_dynamic_config") {
defines = [ "CODEC_IMPL_INTERNAL_ENABLE_DYNAMIC_BUFFERS=0" ]
}
config("codec_impl_dynamic_config") {
defines = [ "CODEC_IMPL_INTERNAL_ENABLE_DYNAMIC_BUFFERS=1" ]
}
_codec_impl_internal_sources = [
"codec_adapter.cc",
"codec_adapter_events.cc",
"codec_admission_control.cc",
"codec_buffer.cc",
"codec_diagnostics.cc",
"codec_frame.cc",
"codec_impl.cc",
"codec_input_item.cc",
"codec_metrics.cc",
"codec_packet.cc",
"codec_vmo_range.cc",
"decryptor_adapter.cc",
"fake_map_range.cc",
"log.cc",
"utils.h",
]
_codec_impl_internal_public = [
# Not intended for codec_impl clients to include directly, but needed by
# local dependent targets:
"dispatcher.h",
"include/lib/media/codec_impl/codec_adapter.h",
"include/lib/media/codec_impl/codec_adapter_events.h",
"include/lib/media/codec_impl/codec_admission_control.h",
"include/lib/media/codec_impl/codec_buffer.h",
"include/lib/media/codec_impl/codec_diagnostics.h",
"include/lib/media/codec_impl/codec_impl.h",
"include/lib/media/codec_impl/codec_input_item.h",
"include/lib/media/codec_impl/codec_metrics.h",
"include/lib/media/codec_impl/codec_packet.h",
"include/lib/media/codec_impl/codec_vmo_range.h",
"include/lib/media/codec_impl/decryptor_adapter.h",
]
_codec_impl_internal_public_deps = [
":fourcc",
"//sdk/fidl/fuchsia.media:fuchsia.media_cpp",
"//sdk/fidl/fuchsia.media.drm:fuchsia.media.drm_hlcpp",
"//sdk/fidl/fuchsia.mediacodec:fuchsia.mediacodec_hlcpp",
"//sdk/fidl/fuchsia.sysmem2:fuchsia.sysmem2_cpp",
"//sdk/lib/async:async-cpp",
"//sdk/lib/async-loop:async-loop-cpp",
"//sdk/lib/async-loop:async-loop-default",
"//sdk/lib/fit",
"//sdk/lib/inspect/component/cpp",
"//src/lib/ddk",
"//src/lib/metrics_buffer",
"//src/media/lib/blocking_mpsc_queue",
"//src/media/lib/metrics",
"//zircon/system/ulib/closure-queue",
"//zircon/system/ulib/fbl",
"//zircon/system/ulib/inspect",
"//zircon/system/ulib/sync:sync-cpp",
"//zircon/system/ulib/sysmem-version",
"//zircon/system/ulib/thread-safe-deleter",
"//zircon/system/ulib/trace",
"//zircon/system/ulib/trace-vthread",
"//zircon/third_party/ulib/safemath",
]
_codec_impl_internal_deps = [
"//sdk/fidl/fuchsia.images2:fuchsia.images2_cpp_hlcpp_conversion",
"//sdk/fidl/fuchsia.media:fuchsia.media_hlcpp",
"//sdk/fidl/fuchsia.sysmem:fuchsia.sysmem_cpp_hlcpp_conversion",
"//sdk/lib/memory_barriers",
"//sdk/lib/sys/cpp",
"//sdk/lib/syslog/cpp",
"//sdk/lib/vfs/cpp",
"//src/devices/bind/fuchsia.sysmem.heap:fuchsia.sysmem.heap_cpp",
"//zircon/system/ulib/sync:sync-cpp",
]
source_set("codec_impl_internal_no_dynamic") {
sources = _codec_impl_internal_sources
public = _codec_impl_internal_public
public_deps = _codec_impl_internal_public_deps
deps = _codec_impl_internal_deps
public_configs = [
":codec_impl_include_config",
":codec_impl_no_dynamic_config",
]
}
source_set("codec_impl_internal_dynamic") {
sources = _codec_impl_internal_sources
public = _codec_impl_internal_public
public_deps = _codec_impl_internal_public_deps
deps = _codec_impl_internal_deps
public_configs = [
":codec_impl_include_config",
":codec_impl_dynamic_config",
]
}
# non-driver/DFv1 variant (see codec_impl_dfv2 for DFv2 variant)
#
# This uses async::Loop (not DFv2 fdf::SynchronizedDispatcher; see
# codec_impl_dfv2).
#
# Logs via fprintf.
source_set("codec_impl") {
sources = [
"dispatcher_via_async_loop.cc",
"log_via_fprintf.cc",
]
public_deps = [
":codec_impl_internal_no_dynamic",
"//src/lib/fxl",
]
}
# Non-driver variant with dynamic buffer support enabled
# (CODEC_IMPL_INTERNAL_ENABLE_DYNAMIC_BUFFERS=1), used by unit tests and
# components that exercise dynamic buffer lifetimes.
source_set("codec_impl_dynamic") {
sources = [
"dispatcher_via_async_loop.cc",
"log_via_fprintf.cc",
]
public_deps = [
":codec_impl_internal_dynamic",
"//src/lib/fxl",
]
}
# DFv1 driver variant
#
# This uses async::Loop (not DFv2 fdf::SynchronizedDispatcher; see
# codec_impl_dfv2).
#
# This logs via zxlogvf.
source_set("codec_impl_dfv1") {
sources = [
"dispatcher_via_async_loop.cc",
"log_via_dfv1.cc",
]
public_deps = [
":codec_impl_internal_no_dynamic",
"//src/lib/ddk",
]
}
# Variant for non-driver/SW codecs using syslog logging
source_set("codec_impl_syslog") {
sources = [
"dispatcher_via_async_loop.cc",
"log_via_syslog.cc",
]
public_deps = [
":codec_impl_internal_no_dynamic",
"//sdk/lib/syslog/cpp",
"//src/lib/fxl",
]
}
# DFv2 variant (see codec_impl for non-driver/DFv1 variant)
#
# This avoids depending on async::Loop, whose StartThread is disallowed in DFv2.
#
# This uses DFv2 fdf::SynchronizedDispatcher.
source_set("codec_impl_dfv2") {
sources = [
"dispatcher_via_fdf_dispatcher.cc",
"log_via_fdf.cc",
]
public_deps = [
":codec_impl_internal_dynamic",
"//src/lib/ddk",
]
}
group("tests") {
testonly = true
deps = [ "unit_tests" ]
}