src/identity/tests/google_signin_e2e/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/dart/test.gni")
import("//topaz/runtime/flutter_runner/flutter_app.gni")

flutter_jit_app("google_signin_e2e_tester") {
  main_dart = "lib/main.dart"

  package_name = "google_signin_e2e_tester"

  meta = [
    {
      path = rebase_path("meta/google_signin_e2e_tester.cmx")
      dest = "google_signin_e2e_tester.cmx"
    },
  ]

  deps = [
    "//sdk/fidl/fuchsia.auth",
    "//sdk/fidl/fuchsia.ui.views",
    "//topaz/lib/settings:lib.settings",
    "//topaz/public/dart/fidl",
    "//topaz/public/dart/fuchsia_inspect",
    "//topaz/public/dart/fuchsia_logger",
    "//topaz/public/dart/fuchsia_scenic_flutter",
    "//topaz/public/dart/fuchsia_services",
    "//topaz/public/dart/widgets:lib.widgets",
  ]
}

dart_test("google_signin_e2e_test") {
  sources = [
    "google_signin_test.dart",
  ]

  deps = [
    "//sdk/testing/sl4f/client",
    "//third_party/dart-pkg/pub/matcher",
    "//third_party/dart-pkg/pub/test",
    "//third_party/dart-pkg/pub/webdriver",
  ]

  non_dart_deps = [ ":runtime_deps" ]
}

copy("runtime_deps") {
  _data_dir = "$target_gen_dir/runtime_deps"

  sources = [
    "//prebuilt/third_party/chromedriver/linux-x64/chromedriver",
  ]

  outputs = [
    "$_data_dir/{{source_file_part}}",
  ]
}

group("test") {
  testonly = true

  deps = [
    ":google_signin_e2e_test",
    ":google_signin_e2e_tester",
  ]
}