garnet/lib/rust/files_async/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/rust/rustc_library.gni")
import("//build/testing/environments.gni")
import("//src/sys/build/components.gni")

rustc_library("files_async") {
  with_unit_tests = true
  edition = "2018"
  deps = [
    "//sdk/fidl/fuchsia.io:fuchsia.io-rustc",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/zircon/rust:fuchsia-zircon-status",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:thiserror",
  ]
  test_deps = [
    "//garnet/lib/rust/io_util",
    "//src/lib/storage/vfs/rust:vfs",
    "//third_party/rust_crates:matches",
    "//third_party/rust_crates:pin-utils",
    "//third_party/rust_crates:proptest",
    "//third_party/rust_crates:tempfile",
  ]

  sources = [ "src/lib.rs" ]

  if (is_fuchsia) {
    deps += [
      "//src/lib/fuchsia-async",
      "//src/lib/zircon/rust:fuchsia-zircon",
    ]
  }
}

fuchsia_unittest_package("files_async_tests") {
  manifest = "meta/files_async_lib_test.cmx"
  deps = [ ":files_async_test" ]

  test_specs = {
    environments = [ emu_env ]
  }
}