zircon/system/ulib/cobalt-client/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("types-internal") {
  public = [
    "cpp/types-internal.h",
  ]
  public_deps = [
    "$zx/system/fidl/fuchsia-cobalt:llcpp",
  ]
  visibility = [ "./*" ]
}

source_set("collector") {
  sources = [
    "cobalt_logger.cc",
    "collector.cc",
  ]
  public_deps = [
    "$zx/system/ulib/fit",
    "$zx/system/ulib/zx",
  ]
  include_dirs = [ "./include/" ]
  deps = [
    ":types-internal",
    "$zx/system/fidl/fuchsia-cobalt:llcpp",
    "$zx/system/fidl/fuchsia-cobalt:llcpp",
    "$zx/system/public",
    "$zx/system/ulib/fdio",
  ]
  visibility = [ "./*" ]
}

source_set("metrics") {
  sources = [
    "counter.cc",
    "histogram.cc",
  ]
  include_dirs = [ "./include/" ]
  public_deps = [
    ":collector",
    ":types-internal",
    "$zx/system/public",
  ]
  visibility = [ "./*" ]
}

zx_library("cobalt-client") {
  sources = []
  public_deps = [
    ":collector",
    ":metrics",
  ]
}

# This library may only be imported from tests.
zx_library("in-memory-logger") {
  testonly = true
  sources = [
    "in_memory_logger.cc",
  ]
  public_deps = [
    ":metrics",
  ]
  deps = [
    ":types-internal",
  ]
}