src/developer/tracing/lib/test_utils/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/test/test_package.gni")

source_set("test_utils") {
  testonly = true

  sources = [
    "run_program.cc",
    "run_program.h",
  ]

  public_deps = [
    "//sdk/lib/fdio",
    "//sdk/lib/sys/cpp",
    "//src/lib/fxl",
    "//zircon/public/lib/zx",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
  ]

  deps = [ "//src/lib/fsl" ]
}

executable("tracing_test_utils_tests_app") {
  testonly = true
  output_name = "tracing_test_utils_tests"

  sources = [ "run_program_tests.cc" ]

  deps = [
    ":test_utils",
    "//src/lib/fxl/test:gtest_main",
  ]
}

executable("tracing_test_utils_return_1234") {
  testonly = true

  sources = [ "return_1234.cc" ]
}

executable("tracing_test_utils_signal_peer") {
  testonly = true

  sources = [ "signal_peer.cc" ]

  deps = [ "//zircon/public/lib/zx" ]
}

test_package("tracing_test_utils_tests") {
  deps = [
    ":tracing_test_utils_return_1234",
    ":tracing_test_utils_signal_peer",
    ":tracing_test_utils_tests_app",
  ]

  binaries = [
    {
      name = "tracing_test_utils_return_1234"
      dest = "return_1234"
    },
    {
      name = "tracing_test_utils_signal_peer"
      dest = "signal_peer"
    },
  ]

  tests = [
    {
      name = "tracing_test_utils_tests"
    },
  ]
}