sdk/lib/inspect/contrib/cpp/tests/BUILD.gn

#Copyright 2018 The Fuchsia Authors.All rights reserved.
#Use of this source code is governed by a BSD - style license that can be
#found in the LICENSE file.

import("//build/components.gni")

group("tests") {
  testonly = true
  deps = [ ":archive_reader_integration_tests" ]
}

executable("bin") {
  output_name = "archive_reader_test_app"

  sources = [ "program.cc" ]

  deps = [
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/inspect/cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

executable("test") {
  testonly = true
  output_name = "archive_reader_integration_tests"

  sources = [ "test.cc" ]

  deps = [
    "//sdk/lib/inspect/contrib/cpp:archive_reader",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:integration_fixture",
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gmock",
  ]
}

fuchsia_component("archive_reader_test_app") {
  testonly = true
  manifest = "meta/archive_reader_test_app.cmx"
  deps = [ ":bin" ]
}

fuchsia_component("archive_reader_test_app_2") {
  testonly = true
  manifest = "meta/archive_reader_test_app_2.cmx"
  deps = [ ":bin" ]
}

fuchsia_test_component("archive_reader_tests") {
  manifest = "meta/archive_reader_integration_tests.cmx"
  deps = [ ":test" ]
}

fuchsia_test_package("archive_reader_integration_tests") {
  package_deps_for_infra_only =
      [ "//src/diagnostics/archivist:archivist-for-embedding" ]
  test_components = [ ":archive_reader_tests" ]
  deps = [
    ":archive_reader_test_app",
    ":archive_reader_test_app_2",
  ]
}