src/lib/trace/rust/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/rust/rustc_library.gni")
import("//build/test/test_package.gni")

rustc_library("trace") {
  name = "fuchsia_trace"
  with_unit_tests = true
  edition = "2018"
  deps = [
    "//src/lib/cstr",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:libc",
  ]
  non_rust_deps = [ "//zircon/public/lib/trace-engine" ]
}

unittest_package("rust-trace-test") {
  deps = [ ":trace_test" ]
  tests = [
    {
      name = "fuchsia_trace_lib_test"
      environments = basic_envs
    },
  ]
}

group("tests") {
  testonly = true
  deps = [ ":rust-trace-test" ]
}

shared_library("rust-trace-provider") {
  visibility = [ ":*" ]
  deps = [
    "//zircon/public/lib/async-loop-cpp",
    "//zircon/public/lib/async-loop-default",
    "//zircon/public/lib/trace-provider-with-fdio",
  ]
  sources = [ "trace-provider/trace_provider.cc" ]
}

rustc_library("trace-provider") {
  name = "fuchsia_trace_provider"
  edition = "2018"
  source_root = "trace-provider/src/lib.rs"
  non_rust_deps = [
    ":rust-trace-provider",
    "//zircon/public/lib/trace-provider-with-fdio",
  ]
}