src/developer/forensics/feedback_data/system_log_recorder/encoding/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

###############################################################################
# SOURCES
###############################################################################
source_set("decoder") {
  sources = [ "decoder.h" ]
  public_deps = [ ":version" ]
}

source_set("encoder") {
  sources = [ "encoder.h" ]
  public_deps = [ ":version" ]
}

source_set("identity_decoder") {
  sources = [ "identity_decoder.h" ]

  public_deps = [
    ":decoder",
    ":version",
  ]
}

source_set("identity_encoder") {
  sources = [ "identity_encoder.h" ]

  public_deps = [
    ":encoder",
    ":version",
  ]
}

source_set("lz4_decoder") {
  sources = [
    "lz4_decoder.cc",
    "lz4_decoder.h",
    "lz4_utils.h",
  ]

  public_deps = [
    ":decoder",
    ":version",
    "//zircon/third_party/ulib/lz4",
  ]

  deps = [
    ":lz4_utils",
    ":ring_buffer",
    "//src/lib/fxl",
  ]
}

source_set("lz4_encoder") {
  sources = [
    "lz4_encoder.cc",
    "lz4_encoder.h",
    "lz4_utils.h",
  ]

  public_deps = [
    ":encoder",
    ":version",
    "//zircon/third_party/ulib/lz4",
  ]

  deps = [
    ":lz4_utils",
    ":ring_buffer",
    "//sdk/lib/syslog/cpp",
  ]
}

source_set("lz4_utils") {
  sources = [ "lz4_utils.h" ]

  public_deps = [
    "//src/developer/forensics/feedback_data:constants",
    "//zircon/third_party/ulib/lz4",
  ]
}

source_set("production") {
  sources = [ "production_encoding.h" ]

  public_deps = [
    ":lz4_decoder",
    ":lz4_encoder",
  ]
}

source_set("ring_buffer") {
  sources = [
    "ring_buffer.cc",
    "ring_buffer.h",
  ]

  deps = [
    ":lz4_utils",
    "//sdk/lib/syslog/cpp",
  ]
}

source_set("version") {
  sources = [
    "version.cc",
    "version.h",
  ]

  public_deps = [ "//src/developer/forensics/utils/cobalt" ]
}