sdk/lib/sys/inspect/cpp/tests/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//build/test/test_package.gni")
import("//build/testing/environments.gni")

executable("bin") {
  output_name = "sys_inspect_cpp_bin"
  sources = [ "program.cc" ]
  deps = [
    "//sdk/lib/sys/inspect/cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/inspect",
  ]
  libs = [ "zircon" ]
}

executable("test") {
  testonly = true
  output_name = "sys_inspect_cpp_tests"
  sources = [ "test.cc" ]
  deps = [
    "//sdk/fidl/fuchsia.inspect",
    "//sdk/lib/inspect/service/cpp",
    "//sdk/lib/inspect/testing/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:integration",
    "//src/lib/fxl",
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gmock",
    "//zircon/system/ulib/inspect",
  ]
  public_deps = [
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gmock",
  ]
  libs = [ "zircon" ]

  # TODO(46843): Fix the leaks and remove this.
  deps += [ "//build/config/sanitizers:suppress-lsan.DO-NOT-USE-THIS" ]
}

test_package("sys_inspect_cpp_tests") {
  deps = [
    ":bin",
    ":test",
  ]

  binaries = [
    {
      name = "sys_inspect_cpp_bin"
    },
  ]

  meta = [
    {
      path = rebase_path("meta/sys_inspect_cpp_bin.cmx")
      dest = "sys_inspect_cpp_bin.cmx"
    },
  ]

  tests = [
    {
      name = "sys_inspect_cpp_tests"
      environments = basic_envs
    },
  ]
}