src/storage/nand/drivers/ram-nand/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/fuchsia/rules.gni")
import("//build/test.gni")
import("//build/unification/images/migrated_manifest.gni")

driver_module("ram-nand") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [
    "bind.cc",
    "ram-nand-ctl.cc",
  ]
  deps = [
    ":common",
    "//sdk/banjo/ddk.protocol.nand",
    "//src/devices/lib/driver",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/fidl",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zircon-internal",
    "//zircon/public/lib/zx",
    "//zircon/system/fidl/fuchsia-hardware-nand:c",
  ]
}

source_set("common") {
  visibility = [ ":*" ]
  sources = [ "ram-nand.cc" ]
  deps = [
    "//sdk/banjo/ddk.protocol.nand",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zircon-internal",
    "//zircon/system/fidl/fuchsia-hardware-nand:c",
  ]
}

test("ram-nand-test") {
  # Dependent manifests unfortunately cannot be marked as `testonly`.
  # Remove when converting this file to proper GN build idioms.
  testonly = false
  configs += [ "//build/unification/config:zircon-migrated" ]
  output_name = "ram-nand-test"
  sources = [
    "test/ram-nand-ctl.cc",
    "test/ram-nand.cc",
  ]
  include_dirs = [ "." ]
  deps = [
    ":common",
    "//sdk/banjo/ddk.protocol.nand",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/devmgr-integration-test",
    "//zircon/public/lib/devmgr-launcher",
    "//zircon/public/lib/fake_ddk",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/fdio",
    "//zircon/public/lib/fdio-caller",
    "//zircon/public/lib/fzl",
    "//zircon/public/lib/ramdevice-client",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/unittest",
    "//zircon/public/lib/zircon-internal",
    "//zircon/public/lib/zx",
    "//zircon/public/lib/zxtest",
    "//zircon/system/fidl/fuchsia-hardware-nand:c",
  ]
}

migrated_manifest("ram-nand-manifest") {
  deps = [ ":ram-nand" ]
}

migrated_manifest("ram-nand-test-manifest") {
  deps = [ ":ram-nand-test" ]
}