src/camera/drivers/bus/aml_mipicsi/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/config/fuchsia/rules.gni")
import("//build/driver_package.gni")

bind_rules("aml_mipi_bind") {
  rules = "aml_mipi.bind"
  output = "bind.h"
  tests = "bind_tests.json"
  deps = [ "//src/devices/bind/fuchsia.platform" ]
}

group("bind_test") {
  testonly = true
  deps = [ ":aml_mipi_bind_test" ]
}

driver_module("aml_mipicsi_driver") {
  output_name = "aml_mipicsi"
  sources = [
    "aml_mipi.cc",
    "aml_mipi.h",
    "aml_mipi_adap.cc",
    "aml_mipi_debug.cc",
    "aml_mipi_regs.h",
  ]
  deps = [
    ":aml_mipi_bind",
    "//sdk/banjo/ddk.protocol.mipicsi",
    "//sdk/banjo/ddk.protocol.platform.bus",
    "//sdk/banjo/ddk.protocol.platform.device",
    "//src/devices/bus/lib/device-protocol-pdev",
    "//src/devices/bus/lib/device-protocol-platform-device",
    "//src/devices/lib/driver",
    "//src/devices/lib/mmio",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//zircon/public/lib/zx",
    "//zircon/system/ulib/fzl",
  ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
}

driver_package("driver_package") {
  package_name = "aml-mipicsi"
  deps = [ ":aml_mipicsi_driver" ]

  drivers = [
    {
      name = "aml_mipicsi.so"
    },
  ]
}

group("aml_mipicsi") {
  deps = [ ":driver_package" ]
}