src/ui/input/drivers/focaltech/meta/focaltech.bind

// Copyright 2021 The Fuchsia Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.

composite focaltech_touch;
using fuchsia;
using fuchsia.gpio;
using fuchsia.platform;

primary parent "i2c" {
  fuchsia.Service == "fuchsia.hardware.i2c.Service";
}

parent "gpio-int" {
  fuchsia.Service == "fuchsia.hardware.gpio.Service";
  fuchsia.NAME == "gpio-int";
}

parent "gpio-reset" {
  fuchsia.Service == "fuchsia.hardware.gpio.Service";
  fuchsia.NAME == "gpio-reset";
}

parent "pdev" {
  fuchsia.BIND_PLATFORM_DEV_VID == fuchsia.platform.BIND_PLATFORM_DEV_VID.GENERIC;
  if fuchsia.BIND_PLATFORM_DEV_DID == fuchsia.platform.BIND_PLATFORM_DEV_DID.FOCALTOUCH {
    fuchsia.BIND_PLATFORM_DEV_PID == fuchsia.platform.BIND_PLATFORM_DEV_PID.GENERIC;
    fuchsia.BIND_PROTOCOL == fuchsia.platform.BIND_PROTOCOL.DEVICE;
    fuchsia.BIND_PLATFORM_DEV_INSTANCE_ID == 0;
  } else {
    accept fuchsia.COMPATIBLE {
      "focaltech,ft3x27",
      "focaltech,ft6336",
      "focaltech,ft5726",
      "focaltech,ft5336",
    }
  }
}

optional parent "gpio-init" {
  fuchsia.BIND_INIT_STEP == fuchsia.gpio.BIND_INIT_STEP.GPIO;
}

optional parent "pin-states-0" {
  fuchsia.Service == "fuchsia.hardware.pin.PinStatesService";
}