src/tests/fidl/dynsuite/client_suite/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

runners = [
  "cpp_async",
  "cpp_sync",
  "cpp_wire_async",
  "cpp_wire_sync",
  "go",
  "hlcpp_async",
  "hlcpp_sync",
  "rust_async",
  "rust_sync",
]

fuchsia_test_component("test_component") {
  component_name = "test"
  manifest = "meta/test.cml"
}

foreach(runner, runners) {
  fuchsia_test_package("fidl_client_suite_${runner}_test") {
    subpackages = [ "//src/tests/fidl/dynsuite/client_suite/harness" ]
    renameable_subpackages = [
      {
        name = "client"
        package = "//src/tests/fidl/dynsuite/client_suite/runners/${runner}"
      },
    ]
    test_components = [ ":test_component" ]
  }
}

group("client_suite") {
  testonly = true

  deps = []
  foreach(runner, runners) {
    deps += [ ":fidl_client_suite_${runner}_test" ]
  }
}