src/sys/test_runners/gotests/tests/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_test.gni")

rustc_test("tests_bin") {
  edition = "2024"
  source_root = "main.rs"
  name = "go_runner_integration_test"

  deps = [
    "//sdk/fidl/fuchsia.test.manager:fuchsia.test.manager_rust",
    "//src/lib/fuchsia-async",
    "//src/sys/test_manager:test_lib",
    "//src/sys/test_runners:test_lib",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:pretty_assertions",
    "//third_party/rust_crates:regex",
  ]

  sources = [ "main.rs" ]
}

fuchsia_test_component("go_runner_integration_test") {
  manifest = "meta/go_runner_integration_test.cml"
  deps = [ ":tests_bin" ]
  test_type = "test_arch"
}

fuchsia_test_package("go-runner-integration-test") {
  test_components = [ ":go_runner_integration_test" ]
  subpackages = [
    "//src/sys/test_manager:pkg",
    "../test_data:go-test-runner-example",
  ]
}

group("tests") {
  testonly = true
  deps = [
    ":go-runner-integration-test",
    "../test_data",
  ]
}