src/sys/lib/runtime_capabilities/BUILD.gn

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_library.gni")

group("tests") {
  testonly = true
  deps = [ ":runtime_capabilities-unittests" ]
}

rustc_library("runtime_capabilities") {
  edition = "2024"
  with_unit_tests = true

  deps = [
    "//sdk/fidl/fuchsia.component.runtime:fuchsia.component.runtime_rust",
    "//sdk/fidl/fuchsia.component.sandbox:fuchsia.component.sandbox_rust",
    "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
    "//sdk/rust/zx-status",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/from-enum",
    "//src/lib/fuchsia-sync",
    "//src/sys/component_manager/lib/router_error",
    "//src/sys/lib/capability_source",
    "//src/sys/lib/cm_types",
    "//third_party/rust_crates:async-trait",
    "//third_party/rust_crates:derivative",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:itertools",
    "//third_party/rust_crates:thiserror",
  ]

  test_deps = [
    "//src/lib/fdio/rust:fdio",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-fs",
    "//src/lib/sandbox",
    "//src/lib/test_util",
    "//third_party/rust_crates:assert_matches",
    "//third_party/rust_crates:test-case",
  ]

  sources = [
    "src/capability.rs",
    "src/connector.rs",
    "src/data.rs",
    "src/dictionary.rs",
    "src/dir_connector.rs",
    "src/fidl/capability.rs",
    "src/fidl/connector.rs",
    "src/fidl/connector_router.rs",
    "src/fidl/data.rs",
    "src/fidl/data_router.rs",
    "src/fidl/dictionary.rs",
    "src/fidl/dictionary_router.rs",
    "src/fidl/dir_connector.rs",
    "src/fidl/dir_connector_router.rs",
    "src/fidl/handle.rs",
    "src/fidl/instance_token.rs",
    "src/fidl/mod.rs",
    "src/fidl/receiver.rs",
    "src/fidl/router.rs",
    "src/fidl/store.rs",
    "src/handle.rs",
    "src/instance_token.rs",
    "src/lib.rs",
    "src/receiver.rs",
    "src/router.rs",
  ]

  if (!is_host) {
    deps += [
      "//sdk/fidl/fuchsia.component.decl:fuchsia.component.decl_rust",
      "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
      "//sdk/rust/zx",
      "//src/lib/fuchsia-async",
      "//src/storage/lib/vfs/rust:vfs",
      "//third_party/rust_crates:log",
      "//third_party/rust_crates:scopeguard",
    ]
    sources += [ "src/fidl/registry.rs" ]
  }
}

fuchsia_unittest_package("runtime_capabilities-unittests") {
  deps = [ ":runtime_capabilities_test" ]
}