src/sys/instrumentation_data_processor/BUILD.gn

# Copyright 2024 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/test.gni")

executable("instrumentation_data_processor_bin") {
  sources = [
    "instrumentation_data_processor.cc",
    "instrumentation_data_publisher.cc",
  ]
  deps = [
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//sdk/lib/syslog/cpp",
  ]

  public_deps = [ "//zircon/system/ulib/debugdata" ]
}

# TODO: https://fxbug.dev/42068707 - This component is under construction.
fuchsia_component("instrumentation_data_processor_component") {
  component_name = "instrumentation_data_processor"
  manifest = "meta/instrumentation_data_processor.cml"
  deps = [ ":instrumentation_data_processor_bin" ]
}

fuchsia_package("instrumentation_data_processor_pkg") {
  package_name = "instrumentation_data_processor"
  deps = [
    ":instrumentation_data_processor_component",
    "//src/storage/memfs:memfs_component",
  ]
}

test("instrumentation_data_processor_test") {
  output_name = "instrumentation_data_processor_test"
  sources = [ "instrumentation_data_processor_test.cc" ]
  deps = [
    "//src/lib/fxl/test:gtest_main",
    "//zircon/system/ulib/fbl",
  ]

  public_deps = [ "//zircon/system/ulib/debugdata" ]
}

fuchsia_unittest_package("instrumentation_data_processor_tests") {
  manifest = "meta/instrumentation_data_processor_test.cml"
  deps = [
    ":instrumentation_data_processor_component",
    ":instrumentation_data_processor_test",
  ]
}

group("tests") {
  testonly = true
  deps = [ ":instrumentation_data_processor_tests" ]
}