src/sys/fuzzing/realmfuzzer/testing/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components/fuchsia_test_component.gni")
import("//build/testing/cc_test_executable.gni")

# This source set contains various fakes used in realmfuzzer unit tests.
source_set("testing") {
  visibility = [ "../*" ]
  testonly = true
  sources = [
    "adapter.cc",
    "adapter.h",
    "coverage.cc",
    "coverage.h",
    "module.cc",
    "module.h",
    "target-main.h",
    "target.cc",
    "target.h",
  ]
  public_deps = [
    "../engine:engine-lib",
    "../target:no_hooks",
    "//src/sys/fuzzing/common",
    "//src/sys/fuzzing/common/testing",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/zx",
  ]
  deps = [ "//sdk/lib/fdio" ]
}

# This executable is used for unit tests that manipulate processes.
cc_test_executable("test-target") {
  output_name = "realmfuzzer_test_target"
  visibility = [ "//src/sys/fuzzing/*" ]
  testonly = true
  sources = [
    "target-main.cc",
    "target-main.h",
  ]
  deps = [
    "//sdk/lib/syslog/cpp",
    "//src/sys/fuzzing/common",
    "//zircon/system/ulib/zx",
  ]
}