src/sys/fuzzing/realmfuzzer/coverage/BUILD.gn

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")

group("tests") {
  testonly = true
  deps = [
    ":unittests-pkg",
    "tests",
  ]
}

rustc_binary("bin") {
  name = "realmfuzzer_coverage"
  with_unit_tests = true
  edition = "2021"
  testonly = true
  sources = [
    "src/aggregator.rs",
    "src/main.rs",
    "src/options.rs",
  ]
  deps = [
    "//build/validate:non_production_tag",
    "//sdk/rust/zx",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component",
    "//src/sys/fuzzing/fidl:fuchsia.fuzzer_rust",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:event-listener",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:log",
  ]
  test_deps = [
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-runtime",
  ]
}

fuchsia_component("coverage") {
  visibility = [
    ":*",
    "//src/sys/fuzzing/realmfuzzer/coverage/tests:*",
    "//src/sys/fuzzing/realmfuzzer/tests:*",
  ]
  testonly = true
  manifest = "meta/coverage.cml"
  deps = [ ":bin" ]
}

fuchsia_component("unittests") {
  visibility = [ ":*" ]
  testonly = true
  manifest = "meta/unittests.cml"
  deps = [ ":bin_test" ]
}

fuchsia_test_package("unittests-pkg") {
  package_name = "realmfuzzer-coverage-unittests"
  test_components = [ ":unittests" ]
}