src/storage/lib/ramdevice_client/cpp/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

config("headers_config") {
  include_dirs = [ "include" ]
}

group("cpp") {
  public_deps = [ ":ramdevice-client" ]
}

source_set("ramdevice-client") {
  public_configs = [ ":headers_config" ]
  public = [
    "include/ramdevice-client/ramdisk.h",
    "include/ramdevice-client/ramnand.h",
  ]
  sources = [
    "ramdisk.cc",
    "ramnand.cc",
  ]
  public_deps = [
    # <ramdevice-client/ramdisk.h> has #include <fidl/fuchsia.hardware.block/cpp/wire.h>
    "//sdk/fidl/fuchsia.hardware.block:fuchsia.hardware.block_cpp",

    # <ramdevice-client/ramnand.h> has #include <fidl/fuchsia.device/cpp/wire.h>
    "//sdk/fidl/fuchsia.device:fuchsia.device_cpp",

    # <ramdevice-client/ramnand.h> has #include <fidl/fuchsia.hardware.nand/cpp/wire.h>
    "//sdk/fidl/fuchsia.hardware.nand:fuchsia.hardware.nand_cpp",

    # <ramdevice-client/ramdisk.h> has #include <zircon/compiler.h>
    "//zircon/system/ulib/zx",
  ]
  deps = [
    "//sdk/fidl/fuchsia.device:fuchsia.device_cpp",
    "//sdk/fidl/fuchsia.hardware.block:fuchsia.hardware.block_cpp",
    "//sdk/fidl/fuchsia.hardware.block.volume:fuchsia.hardware.block.volume_cpp",
    "//sdk/fidl/fuchsia.hardware.ramdisk:fuchsia.hardware.ramdisk_cpp",
    "//sdk/lib/component/incoming/cpp",
    "//sdk/lib/device-watcher/cpp",
    "//sdk/lib/fdio",
    "//sdk/lib/syslog/cpp",
    "//src/lib/ddk",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/fdio-caller",
    "//zircon/system/ulib/fzl",
    "//zircon/system/ulib/zx",
  ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
}

source_set("ramdevice-client-test") {
  testonly = true
  public_configs = [ ":headers_config" ]
  public = [ "include/ramdevice-client-test/ramnandctl.h" ]
  sources = [ "ramnandctl.cc" ]
  public_deps = [
    # <ramdevice-client-test/ramnandctl.h> has #include <ramdevice-client/ramnand.h>
    ":ramdevice-client",

    # <ramdevice-client/ramnand.h> has #include <fidl/fuchsia.device/cpp/wire.h>
    "//sdk/fidl/fuchsia.device:fuchsia.device_cpp",

    # <ramdevice-client/ramnand.h> has #include <fidl/fuchsia.hardware.nand/cpp/wire.h>
    "//sdk/fidl/fuchsia.hardware.nand:fuchsia.hardware.nand_cpp",
    "//sdk/lib/sys/component/cpp/testing:cpp",
    "//zircon/system/ulib/fbl",
  ]
  deps = [
    "//sdk/fidl/fuchsia.device:fuchsia.device_cpp",
    "//sdk/fidl/fuchsia.hardware.block:fuchsia.hardware.block_cpp",
    "//sdk/fidl/fuchsia.hardware.nand:fuchsia.hardware.nand_cpp",
    "//sdk/fidl/fuchsia.hardware.ramdisk:fuchsia.hardware.ramdisk_cpp",
    "//sdk/lib/device-watcher/cpp",
    "//sdk/lib/fdio",
    "//src/lib/ddk",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/fdio-caller",
    "//zircon/system/ulib/fzl",
    "//zircon/system/ulib/zx",
  ]
}