src/performance/memory/stacktrack/lib/stacktrack_snapshot/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_library.gni")
import("//tools/fidl/measure-tape/measure_tape.gni")

measure_tape("measure_tape_for_snapshot_element") {
  target_binding = "rust"
  target_types = [ "fuchsia.memory.stacktrack.client/SnapshotElement" ]
  fidls = [ "//sdk/fidl/fuchsia.memory.stacktrack.client" ]
}

template("stacktrack_snapshot_lib") {
  rustc_library(target_name) {
    edition = "2024"
    with_unit_tests = true

    sources = [
      "src/lib.rs",
      "src/snapshot.rs",
      "src/streamer.rs",
    ]

    deps = [
      ":measure_tape_for_snapshot_element",
      "//sdk/rust/zx-types",
      "//src/lib/fidl/rust/fidl",
      "//third_party/rust_crates:futures",
      "//third_party/rust_crates:thiserror",
    ]
    if (defined(invoker.deps)) {
      deps += invoker.deps
    }

    test_deps = [
      "//src/lib/fuchsia-async",
      "//third_party/rust_crates:futures",
      "//third_party/rust_crates:test-case",
    ]
    if (defined(invoker.test_deps)) {
      test_deps += invoker.test_deps
    }

    features = []
    if (defined(invoker.features)) {
      features += invoker.features
    }
  }
}

stacktrack_snapshot_lib("stacktrack_snapshot") {
  deps = [ "//sdk/fidl/fuchsia.memory.stacktrack.client:fuchsia.memory.stacktrack.client_rust_flex" ]
}

stacktrack_snapshot_lib("stacktrack_snapshot_fdomain") {
  deps = [
    "//sdk/fidl/fuchsia.memory.stacktrack.client:fuchsia.memory.stacktrack.client_rust_fdomain_flex",
    "//src/lib/fdomain/client",
  ]
  test_deps = [ "//src/lib/fdomain/local" ]
  features = [ "fdomain" ]
}

fuchsia_unittest_package("stacktrack-snapshot-tests") {
  package_name = "stacktrack-snapshot-tests"
  deps = [ ":stacktrack_snapshot_test" ]
}

group("tests") {
  testonly = true
  deps = [
    ":stacktrack-snapshot-tests",
    ":stacktrack_snapshot_fdomain_test($host_toolchain)",
  ]
}