src/media/drivers/amlogic_decoder/meta/amlogic_decoder.bind

// Copyright 2021 The Fuchsia Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.

composite aml_video;
using fuchsia;


primary parent "pdev" {
  if fuchsia.BIND_PLATFORM_DEV_VID == fuchsia.platform.BIND_PLATFORM_DEV_VID.GENERIC {
    fuchsia.BIND_PLATFORM_DEV_DID == fuchsia.platform.BIND_PLATFORM_DEV_DID.DEVICETREE;
    accept fuchsia.COMPATIBLE {
      "amlogic,g12a-vdec",
      "amlogic,g12b-vdec",
    }
  } else {
    fuchsia.BIND_PROTOCOL == fuchsia.platform.BIND_PROTOCOL.DEVICE;
    fuchsia.BIND_PLATFORM_DEV_VID == fuchsia.amlogic.platform.BIND_PLATFORM_DEV_VID.AMLOGIC;
    fuchsia.BIND_PLATFORM_DEV_DID == fuchsia.amlogic.platform.BIND_PLATFORM_DEV_DID.VIDEO;
    accept fuchsia.BIND_PLATFORM_DEV_PID {
      fuchsia.amlogic.platform.BIND_PLATFORM_DEV_PID.T931,
      fuchsia.amlogic.platform.BIND_PLATFORM_DEV_PID.A311D,
      fuchsia.amlogic.platform.BIND_PLATFORM_DEV_PID.S905D2,
      fuchsia.amlogic.platform.BIND_PLATFORM_DEV_PID.S905D3,
    }
  }
}

parent "canvas" {
  fuchsia.Service == "fuchsia.hardware.amlogiccanvas.Service";
}

parent "clock-dos-vdec" {
  fuchsia.Service == "fuchsia.hardware.clock.Service";
  fuchsia.NAME == "clock-dos-vdec";
}

parent "clock-dos" {
  fuchsia.Service == "fuchsia.hardware.clock.Service";
  fuchsia.NAME == "clock-dos";
}

optional parent "tee" {
  fuchsia.Service == "fuchsia.hardware.tee.Service";
}