src/graphics/bin/vulkan_loader/test/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/testing/cc_test_executable.gni")

group("tests") {
  testonly = true
  deps = [ ":vulkan_loader_tests" ]
}

cc_test_executable("test_bin") {
  testonly = true
  output_name = "vulkan_loader_test"
  sources = [ "test.cc" ]
  deps = [
    "//sdk/fidl/fuchsia.gpu.magma:fuchsia.gpu.magma_cpp",
    "//sdk/fidl/fuchsia.io:fuchsia.io_cpp",
    "//sdk/fidl/fuchsia.sys2:fuchsia.sys2_cpp",
    "//sdk/fidl/fuchsia.vulkan.loader:fuchsia.vulkan.loader_cpp",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/component/incoming/cpp",
    "//sdk/lib/fdio",
    "//sdk/lib/sys/component/cpp/testing:cpp",
    "//src/lib/fxl:fxl_cli",
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gtest",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/fzl",
  ]
}

cc_test_executable("unittest_bin") {
  testonly = true
  output_name = "vulkan_loader_unittest"
  sources = [ "unittest.cc" ]
  deps = [
    "..:app",
    "//sdk/fidl/fuchsia.io:fuchsia.io_cpp",
    "//sdk/fidl/fuchsia.vulkan.loader:fuchsia.vulkan.loader_cpp",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/fdio",
    "//sdk/lib/sys/cpp",
    "//src/lib/fxl:fxl_cli",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/json_parser",
    "//src/storage/lib/vfs/cpp",
    "//third_party/googletest:gtest",
  ]
}

executable("pkg-server-bin") {
  testonly = true
  output_name = "pkg-server"

  sources = [ "pkg-server-main.cc" ]

  deps = [
    "//sdk/fidl/fuchsia.gpu.magma:fuchsia.gpu.magma_cpp",
    "//sdk/fidl/fuchsia.io:fuchsia.io_cpp",
    "//sdk/fidl/fuchsia.process.lifecycle:fuchsia.process.lifecycle_cpp",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl:fxl_cli",
    "//src/storage/lib/vfs/cpp",
  ]
}

fuchsia_component("vulkan_loader_test_lib_provider_cmp") {
  testonly = true
  component_name = "vulkan_loader_test_lib_provider"
  manifest = "meta/vulkan_loader_test_lib_provider.cml"
  deps = [ ":pkg-server-bin" ]
}

fuchsia_component("vulkan_loader_test") {
  testonly = true
  manifest = "meta/vulkan_loader_test.cml"
  deps = [ ":test_bin" ]
}

fuchsia_component("vulkan_loader_unittest_driver") {
  testonly = true
  manifest = "meta/vulkan_loader_unittest_driver.cml"
  deps = [ ":unittest_bin" ]
}

fuchsia_component("vulkan_loader_unittest") {
  testonly = true
  manifest = "meta/vulkan_loader_unittest.cml"
}

resource("metadata") {
  sources = [ "metadata.json" ]
  outputs = [ "data/test_metadata/metadata.json" ]
}

resource("manifest-json") {
  sources = [ "libvulkan_fake.json" ]
  outputs = [ "data/libvulkan_fake.json" ]
}

fuchsia_component("test_vulkan_driver") {
  testonly = true
  manifest = "meta/test_vulkan_driver.cml"
  deps = [ ":metadata" ]
}

fuchsia_component("test_realm") {
  testonly = true
  manifest = "meta/test_realm.cml"
}

fuchsia_test_package("vulkan_loader_tests") {
  test_components = [
    ":vulkan_loader_test",
    ":vulkan_loader_unittest",
  ]
  validate_structured_config = false
  deps = [
    ":manifest-json",
    ":test_realm",
    ":test_vulkan_driver",
    ":vulkan_loader_test_lib_provider_cmp",
    ":vulkan_loader_unittest_driver",
    "..:default_config_values",
    "..:vulkan_loader_cmp",
  ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

fuchsia_package("vulkan_loader_test_lib_provider") {
  testonly = true
  deps = [ ":vulkan_loader_test_lib_provider_cmp" ]
}