src/firmware/lib/fastboot/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

group("fastboot") {
  public_deps = [ ":lib" ]
}

config("include") {
  include_dirs = [ "include" ]
}

source_set("fastboot-base") {
  sources = [ "fastboot_base.cc" ]
  public_configs = [ ":include" ]
  public_deps = [ "//zircon/system/ulib/zx" ]

  if (is_kernel) {
    public_deps += [ "//zircon/kernel/lib/libc" ]
  }
}

source_set("lib") {
  sources = [
    "fastboot.cc",
    "payload-streamer.cc",
    "sparse_format.h",
  ]
  public_configs = [ ":include" ]
  public_deps = [
    ":fastboot-base",
    "rust:fastboot-c",
    "//sdk/fidl/fuchsia.buildinfo:fuchsia.buildinfo_cpp",
    "//sdk/fidl/fuchsia.fshost:fuchsia.fshost_cpp",
    "//sdk/fidl/fuchsia.hardware.power.statecontrol:fuchsia.hardware.power.statecontrol_cpp",
    "//sdk/fidl/fuchsia.paver:fuchsia.paver_cpp",
    "//src/developer/sshd-host:sshd_constants",
    "//third_party/android/platform/system:sparse_format",
    "//zircon/system/ulib/fzl",
    "//zircon/system/ulib/zx",
  ]
  deps = [
    "//sdk/lib/async-default",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/component/incoming/cpp",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl",
    "//zircon/system/ulib/zx",
  ]
}

group("tests") {
  testonly = true
  deps = [
    "rust:tests",
    "test",
  ]
}