src/developer/ffx/tools/gce/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/rust/rustc_library.gni")
import("//src/developer/ffx/build/ffx_tool.gni")

rustc_library("lib") {
  name = "ffx_gce_tool"
  edition = "2024"
  with_unit_tests = true

  deps = [
    "//src/developer/ffx/config:lib",
    "//src/developer/ffx/lib/discovery:lib",
    "//src/developer/ffx/lib/fho:lib",
    "//src/developer/ffx/lib/gce:lib",
    "//src/developer/ffx/lib/pbms:lib",
    "//src/developer/ffx/lib/writer:lib",
    "//src/lib/fuchsia-async",
    "//third_party/rust_crates:argh",
    "//third_party/rust_crates:log",
    "//third_party/rust_crates:prettytable-rs",
    "//third_party/rust_crates:serde",
    "//third_party/rust_crates:tempfile",
  ]

  test_deps = [
    "//build/sdk/meta:rust",
    "//src/lib/fuchsia",
    "//third_party/rust_crates:serde_json",
  ]

  sources = [
    "src/args.rs",
    "src/lib.rs",
    "src/subtools/list.rs",
    "src/subtools/mod.rs",
    "src/subtools/serial.rs",
    "src/subtools/show.rs",
    "src/subtools/start.rs",
    "src/subtools/stop.rs",
  ]
}

ffx_tool("ffx_gce") {
  edition = "2024"
  output_name = "ffx-gce"
  deps = [
    ":lib",
    "//src/developer/ffx/lib/fho:lib",
    "//src/lib/fuchsia-async",
  ]
  sources = [ "src/main.rs" ]
}

group("gce") {
  public_deps = [
    ":ffx_gce",
    ":ffx_gce_host_tool",
  ]
}

group("bin") {
  public_deps = [ ":ffx_gce_versioned" ]
}

group("tests") {
  testonly = true
  deps = [ ":lib_test($host_toolchain)" ]
}