sdk/lib/scheduler/cpp/tests/BUILD.gn

# Copyright 2024 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/test.gni")
import("//build/testing/cc_test_executable.gni")

group("tests") {
  testonly = true
  deps = [ ":role_cpp_lib_test" ]
}

cc_test_executable("role_lib_test_bin") {
  testonly = true
  sources = [ "role_lib.cc" ]
  deps = [
    "//sdk/lib/scheduler/cpp",
    "//zircon/system/ulib/zx",
    "//zircon/system/ulib/zxtest",
  ]
}

resource("config_files") {
  testonly = true
  sources = [ "config/lib_test.profiles" ]
  outputs = [ "profiles/{{source_file_part}}" ]
}

fuchsia_component("role_lib_test") {
  testonly = true
  manifest = "meta/role_lib_test.cml"
  deps = [ ":role_lib_test_bin" ]
}

fuchsia_component("test_realm") {
  testonly = true
  manifest = "meta/test_realm.cml"
}

fuchsia_test_package("role_cpp_lib_test") {
  test_components = [ ":test_realm" ]
  deps = [
    ":config_files",
    ":role_lib_test",
    "//src/zircon/bin/role_manager/testing/fake:fake_role_manager",
  ]
}