sdk/lib/driver/debug/cpp/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/testing/cc_test_executable.gni")

group("tests") {
  testonly = true
  deps = [ ":driver-debug-cpp-test" ]
}

config("includes") {
  include_dirs = [ "include" ]
}

source_set("cpp") {
  sources = [ "debug_server.cc" ]
  public = [ "include/lib/driver/debug/cpp/debug_server.h" ]

  public_deps = [
    "//sdk/fidl/fuchsia.driver.debug:fuchsia.driver.debug_cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//sdk/lib/driver/outgoing/cpp",
    "//sdk/lib/fit",
    "//sdk/lib/stdcompat",
    "//zircon/system/ulib/zx",
  ]

  public_configs = [ ":includes" ]
}

cc_test_executable("cpp_test") {
  testonly = true
  output_name = "driver-debug-cpp-test"
  sources = [ "debug_server_test.cc" ]

  deps = [
    ":cpp",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/component/incoming/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/lib/testing/predicates",
  ]
}

fuchsia_unittest_package("driver-debug-cpp-test") {
  deps = [ ":cpp_test" ]
}