sdk/ctf/tests/fidl/fuchsia.intl/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/component/config.gni")
import("//build/components.gni")
import("//build/fidl/fidl.gni")
import("//build/rust/rustc_binary.gni")
import("//sdk/ctf/build/ctf.gni")

group("tests") {
  testonly = true
  deps = [
    ":ctf-tests",
    ":fuchsia-intl-tests-latest",
  ]
}

group("ctf-tests") {
  testonly = true
  deps = [ ":fuchsia-intl-tests_archive" ]
}

rustc_test("bin") {
  edition = "2021"
  source_root = "src/main.rs"
  sources = [ source_root ]
  name = "fuchsia_intl_test"
  deps = [
    "//sdk/ctf/tests/fidl/fuchsia.intl/testing/fidl:fuchsia.intl.test_rust",
    "//sdk/fidl/fuchsia.intl:fuchsia.intl_rust",
    "//sdk/fidl/fuchsia.settings:fuchsia.settings_rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component",
    "//src/testing/realm_client/rust",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
  ]
}

fuchsia_component("fuchsia-intl-test-component") {
  testonly = true
  component_name = "fuchsia-intl-test"
  manifest = "meta/fuchsia-intl-test.cml"
  deps = [ ":bin" ]
}

ctf_fuchsia_package("fuchsia-intl-tests") {
  package_name = "fuchsia-intl-tests"
  testonly = true
  deps = [ ":fuchsia-intl-test-component" ]
}

fuchsia_test_component("test-root") {
  testonly = true
  manifest = "meta/fuchsia-intl-test-root.cml"
  test_type = "ctf"
}

fuchsia_test_package("fuchsia-intl-tests-latest") {
  test_components = [ ":test-root" ]
  subpackages = [
    "testing/realm-factory",
    ":fuchsia-intl-tests",
  ]
  test_specs = {
    log_settings = {
      min_severity = "DEBUG"
    }
  }
}