products/zedboot/BUILD.gn

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/assembly/product_assembly_configuration.gni")
import("//build/info/info.gni")

zedboot_platform_base = {
  build_type = "eng"
  feature_set_level = "bootstrap"
  development_support = {
    include_netsvc = true
    enable_netsvc_netboot = true
    tools = {
      storage = {
        enable_partitioning_tools = true
      }
    }
  }
  graphics = {
    virtual_console = {
      color_scheme = "special"
      dpi = [
        160,
        240,
        360,
        480,
      ]
    }
  }
}

product_assembly_configuration("zedboot") {
  platform = {
    forward_variables_from(zedboot_platform_base, "*")
    storage = {
      filesystems = {
        image_name = "zedboot"
        image_mode = "no_image"
      }
    }
  }
  product = {
  }
  version = build_info_version
}

product_assembly_configuration("zedboot_with_minfs") {
  platform = {
    forward_variables_from(zedboot_platform_base, "*")
    storage = {
      filesystems = {
        image_name = "zedboot"
        image_mode = "no_image"
        volume = {
          fvm = {
            data = {
              data_filesystem_format = "minfs"
            }
            blob = {
            }
          }
        }
      }
    }
  }
  product = {
  }
  version = build_info_version
}