products/zedboot/BUILD.bazel

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

load("@fuchsia_build_info//:args.bzl", "build_info_version")
load(
    "@rules_fuchsia//fuchsia:assembly.bzl",
    "BUILD_TYPES",
    "fuchsia_product",
    "fuchsia_product_configuration",
)
load("//build/bazel/assembly:zedboot_image_args.bzl", "ZEDBOOT_IMAGE_ARGS", "ZEDBOOT_PLATFORM_BASE")

package(default_visibility = [
    "//build/bazel/assembly:__subpackages__",
    "//products:__subpackages__",
    "//vendor/google:__subpackages__",
])

fuchsia_product_configuration(
    name = "zedboot",
    product_config_json = {
        "platform": ZEDBOOT_PLATFORM_BASE | {
            "storage": {
                "filesystems": {
                    "image_name": "zedboot",
                    "image_mode": "no_image",
                },
            },
        },
    },
    version = build_info_version,
)

[fuchsia_product(
    name = board,
    board_config = "//boards:{}".format(board),
    platform_artifacts = ZEDBOOT_IMAGE_ARGS["platform_artifacts"],
    product_config = "//products/zedboot:zedboot",
) for board in [
    "x64",
    "x64_reduced_perf_variation",
    "arm64",
    "qemu-arm64",
    "vim3",
    "vim3_reduced_perf_variation",
    "riscv64",
]]

# TODO(b/282896655): Remove once this is the default and OOT users have switched off of this.
[fuchsia_product(
    name = "{}_with_fxfs".format(board),
    board_config = "//boards:{}".format(board),
    platform_artifacts = ZEDBOOT_IMAGE_ARGS["platform_artifacts"],
    product_config = "//products/zedboot:zedboot",
) for board in [
    "x64",
    "arm64",
    "vim3",
    "riscv64",
]]