src/connectivity/bluetooth/hci/vendor/mediatek/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

##########################################
# Though under //zircon, this build file #
# is meant to be used in the Fuchsia GN  #
# build.                                 #
# See fxbug.dev/36139.                   #
##########################################

assert(!defined(zx) || zx != "/",
       "This file can only be used in the Fuchsia GN build.")

import("//build/config/fuchsia/rules.gni")
import("//build/test.gni")
import("//build/test/test_package.gni")

import("//build/unification/firmware.gni")

driver_module("bt-hci-mediatek") {
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [
    "//build/config/fuchsia:static_cpp_standard_library",
    "//build/unification/config:zircon-migrated",
  ]
  sources = [ "bt-hci-mediatek.cc" ]
  deps = [
    "//sdk/banjo/ddk.protocol.bt.hci",
    "//sdk/banjo/ddk.protocol.sdio",
    "//src/devices/bus/lib/device-protocol-pdev",
    "//src/devices/lib/driver",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zircon-internal",
    "//zircon/public/lib/zx",
    "//zircon/system/ulib/fzl",

    # TODO(fxb/38132): Migrate to the new bind rules and delete the below
    "//src/lib/ddk:ddk-deprecated-binding-headers",
  ]
  data_deps = [ ":firmware" ]
}

firmware("firmware") {
  sources = [ "bluetooth/mt7668/mt7668_patch_e2_hdr.bin" ]
}

test("bt-hci-mediatek-test") {
  configs += [ "//build/unification/config:zircon-migrated" ]
  output_name = "bt-hci-mediatek-test"
  configs += [ "//build/config:all_source" ]
  sources = [
    "bt-hci-mediatek-test.cc",
    "bt-hci-mediatek.cc",
  ]
  deps = [
    "//sdk/banjo/ddk.protocol.bt.hci",
    "//sdk/banjo/ddk.protocol.sdio",
    "//sdk/lib/fdio",
    "//src/devices/bus/lib/device-protocol-pdev",
    "//src/devices/bus/testing/mock-sdio",
    "//src/devices/testing/fake_ddk",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/mock-function",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zircon-internal",
    "//zircon/public/lib/zx",
    "//zircon/public/lib/zxtest",
    "//zircon/system/ulib/fzl",

    # TODO(fxb/38132): Migrate to the new bind rules and delete the below
    "//src/lib/ddk:ddk-deprecated-binding-headers",
  ]
}

unittest_package("bt-hci-mediatek-test-package") {
  package_name = "bt-hci-mediatek-test"
  deps = [ ":bt-hci-mediatek-test" ]

  tests = [
    {
      name = "bt-hci-mediatek-test"
      environments = basic_envs
    },
  ]
}

group("tests") {
  testonly = true
  deps = [ ":bt-hci-mediatek-test-package" ]
}