src/devices/tpm/drivers/cr50-spi/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

driver_bind_rules("cr50-spi_bind") {
  rules = "meta/cr50-spi.bind"
  tests = "meta/bind_tests.json"
  deps = [
    "//sdk/fidl/fuchsia.hardware.interrupt:fuchsia.hardware.interrupt_bindlib",
    "//src/devices/bind/fuchsia.acpi",
  ]
}

common_deps = [
  ":cr50-spi_bind",
  "//sdk/banjo/fuchsia.hardware.tpmimpl:fuchsia.hardware.tpmimpl_banjo_cpp",
  "//sdk/fidl/fuchsia.hardware.spi:fuchsia.hardware.spi_cpp",
  "//sdk/fidl/fuchsia.hardware.tpmimpl:fuchsia.hardware.tpmimpl_cpp",
  "//sdk/lib/async:async-cpp",
  "//sdk/lib/async-loop:async-loop-cpp",
  "//src/devices/lib/acpi",
  "//src/devices/lib/driver",
  "//src/lib/ddktl",
  "//zircon/system/ulib/inspect",
  "//zircon/system/ulib/zx",
]

fuchsia_cc_driver("fuchsia_driver") {
  output_name = "cr50-spi-driver"
  sources = [ "cr50-spi.cc" ]
  deps = common_deps

  # TODO(https://fxbug.dev/42136089): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

fuchsia_driver_component("cr50-spi-driver") {
  info = "meta/cr50-spi-driver-info.json"
  deps = [ ":fuchsia_driver" ]
  manifest = "meta/cr50-spi.cml"
}

fuchsia_driver_package("cr50-spi-pkg") {
  package_name = "cr50-spi"
  driver_components = [ ":cr50-spi-driver" ]
}

test("cr50-spi-test-bin") {
  output_name = "cr50-spi-test"
  sources = [
    "cr50-spi-test.cc",
    "cr50-spi.cc",
  ]
  deps = common_deps + [
           "//sdk/lib/inspect/testing/cpp:zxtest",
           "//src/devices/lib/acpi/mock:mock-acpi",
           "//src/devices/testing/mock-ddk",
           "//zircon/system/ulib/zxtest",
         ]

  # TODO(https://fxbug.dev/42136089): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

fuchsia_unittest_package("cr50-spi-test") {
  deps = [ ":cr50-spi-test-bin" ]
}

group("cr50-spi") {
  deps = [ ":cr50-spi-pkg" ]
}

group("tests") {
  testonly = true
  deps = [
    ":cr50-spi-test",
    ":cr50-spi_bind_test",
  ]
}