src/sys/pkg/tests/system-update-checker/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/rust/rustc_test.gni")
import("//build/test/test_package.gni")
import("//build/testing/environments.gni")

rustc_test("driver") {
  name = "system_update_checker_integration_test"
  edition = "2018"

  deps = [
    "//sdk/fidl/fuchsia.logger:fuchsia.logger-rustc",
    "//sdk/fidl/fuchsia.update:fuchsia.update-rustc",
    "//sdk/fidl/fuchsia.update.channel:fuchsia.update.channel-rustc",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/sys/pkg/lib/fidl-fuchsia-update-installer-ext",
    "//src/sys/pkg/lib/fuchsia-pkg-testing",
    "//src/sys/pkg/testing/mock-installer",
    "//src/sys/pkg/testing/mock-resolver",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:parking_lot",
    "//third_party/rust_crates:tempfile",
  ]

  sources = [ "src/lib.rs" ]
}

test_package("system-update-checker-integration-tests") {
  deps = [
    ":driver",
    "//src/sys/pkg/bin/system-update-checker:bin",
  ]

  binaries = [
    {
      name = "system_update_checker"
      dest = "system-update-checker"
    },
  ]

  meta = [
    {
      path = rebase_path(
              "//src/sys/pkg/bin/system-update-checker/meta/system-update-checker-for-integration-test.cmx")
      dest = "system-update-checker-for-integration-test.cmx"
    },
  ]

  tests = [
    {
      name = "system_update_checker_integration_test"
      dest = "system-update-checker-integration-test"
      environments = basic_envs
      log_settings = {
        max_severity = "ERROR"
      }
    },
  ]
}

group("tests") {
  testonly = true
  public_deps = [ ":system-update-checker-integration-tests" ]
}