src/sys/appmgr/integration_tests/inspect/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//build/test/test_package.gni")
import("//build/testing/environments.gni")

group("inspect") {
  testonly = true
  deps = [ ":inspect_vmo_integration_tests" ]
}

executable("bin-vmo") {
  output_name = "inspect_vmo_test_app"

  sources = [ "program-vmo.cc" ]

  deps = [
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/inspect/cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

executable("test-vmo") {
  testonly = true
  output_name = "inspect_vmo_integration_tests"

  sources = [ "test-vmo.cc" ]

  deps = [
    "//sdk/fidl/fuchsia.inspect",
    "//sdk/lib/inspect/testing/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:integration",
    "//src/lib/fxl",
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gmock",
    "//zircon/system/ulib/inspect",
  ]

  # TODO(fxbug.dev/46733): Fix the leaks and remove this.
  deps += [ "//build/config/sanitizers:suppress-lsan.DO-NOT-USE-THIS" ]
}

executable("bin-health") {
  output_name = "inspect_health_test_app"

  sources = [ "program-health.cc" ]

  deps = [
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/inspect/cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

executable("test-health") {
  testonly = true
  output_name = "inspect_health_integration_tests"

  sources = [ "test-health.cc" ]

  deps = [
    "//sdk/fidl/fuchsia.inspect",
    "//sdk/lib/inspect/testing/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:integration",
    "//src/lib/fxl",
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gmock",
    "//zircon/system/ulib/inspect",
  ]

  # TODO(fxbug.dev/46733): Fix the leaks and remove this.
  deps += [ "//build/config/sanitizers:suppress-lsan.DO-NOT-USE-THIS" ]
}

test_package("inspect_vmo_integration_tests") {
  deps = [
    ":bin-health",
    ":bin-vmo",
    ":test-health",
    ":test-vmo",
  ]

  binaries = [
    {
      name = "inspect_vmo_test_app"
    },
    {
      name = "inspect_health_test_app"
    },
  ]

  meta = [
    {
      path = rebase_path("meta/inspect_vmo_test_app.cmx")
      dest = "inspect_vmo_test_app.cmx"
    },
    {
      path = rebase_path("meta/inspect_health_test_app.cmx")
      dest = "inspect_health_test_app.cmx"
    },
  ]

  tests = [
    {
      name = "inspect_vmo_integration_tests"
      environments = basic_envs
    },
    {
      name = "inspect_health_integration_tests"
      environments = basic_envs
    },
  ]
}