zircon/system/ulib/zxc/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/zircon/migrated_targets.gni")

sdk_source_set("fitx") {
  category = "experimental"
  sdk_name = "fitx"
  sources = [
    "include/lib/fitx/internal/compiler.h",
    "include/lib/fitx/internal/result.h",
    "include/lib/fitx/result.h",
  ]
}

sdk_source_set("zx") {
  category = "experimental"
  sdk_name = "zx-status"
  sources = [ "include/lib/zx/status.h" ]
  public_deps = [ ":fitx" ]
  if (zircon_toolchain != false) {
    public_deps += [ "//zircon/system/public" ]
  }
}

zx_library("zxc") {
  sdk = "source"

  sdk_publishable = "experimental"
  sdk_headers = [
    "lib/fitx/internal/compiler.h",
    "lib/fitx/internal/result.h",
    "lib/fitx/result.h",
    "lib/zx/status.h",
  ]

  sources = []
  deps = []
  public_deps = [
    ":fitx",
    ":zx",
    "//sdk/lib/stdcompat",
  ]

  if (is_fuchsia && !is_kernel) {
    sources += [ "status_string.cc" ]
    deps += [ "//src/zircon/lib/zircon" ]
  }
}