examples/components/runner/colocated/integration_tests/BUILD.gn

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

assert(is_fuchsia, "These targets are only compiled in the fuchsia toolchain.")

import("//build/components.gni")
import("//build/rust/rustc_test.gni")

rustc_test("bin") {
  name = "colocated_runner_integration_test_bin"
  edition = "2021"

  deps = [
    "//examples/components/runner/colocated/fidl:colocated_rust",
    "//sdk/fidl/fuchsia.component:fuchsia.component_rust",
    "//sdk/fidl/fuchsia.component.decl:fuchsia.component.decl_rust",
    "//sdk/fidl/fuchsia.memory.attribution:fuchsia.memory.attribution_rust",
    "//sdk/fidl/fuchsia.process:fuchsia.process_rust",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component-test",
    "//src/lib/fuchsia-runtime",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:async-channel",
    "//third_party/rust_crates:futures-util",
  ]

  sources = [ "src/lib.rs" ]
}

fuchsia_test_component("colocated_runner_integration_test") {
  component_name = "colocated_runner_integration_test"
  manifest = "meta/colocated_runner_integration_test.cml"
  deps = [ ":bin" ]
}

fuchsia_component("test_realm") {
  component_name = "test_realm"
  manifest = "meta/test_realm.cml"
  testonly = true
}

fuchsia_test_package("colocated-runner-integration-test") {
  test_components = [ ":colocated_runner_integration_test" ]
  deps = [
    ":test_realm",
    "//examples/components/runner/colocated:colocated-component",
    "//examples/components/runner/colocated:colocated-runner",
    "//src/sys/component_manager:component-manager-realm-builder-cmp",
    "//src/sys/component_manager:elf_runner",
  ]
}

group("integration_tests") {
  testonly = true
  deps = [ ":colocated-runner-integration-test" ]
}