src/ui/bin/root_presenter/tests/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/test/test_package.gni")
import("//build/testing/environments.gni")

group("tests") {
  testonly = true

  public_deps = [ ":root_presenter_tests" ]
}

test_package("root_presenter_tests") {
  deps = [
    ":root_presenter_apptests",
    ":root_presenter_unittests",
  ]

  tests = [
    {
      name = "root_presenter_apptests"
      environments = basic_envs
    },
    {
      name = "root_presenter_unittests"
      environments = [ nuc_env ]
      log_settings = {
        max_severity = "ERROR"
      }
    },
  ]
}

executable("root_presenter_unittests") {
  testonly = true

  sources = [
    "color_transform_handler_unittest.cc",
    "display_configuration_unittest.cc",
    "factory_reset_manager_test.cc",
    "media_buttons_handler_unittest.cc",
    "root_presenter_unittest.cc",
    "safe_presenter_unittest.cc",
  ]

  deps = [
    "//garnet/public/lib/gtest",
    "//sdk/fidl/fuchsia.accessibility",
    "//sdk/fidl/fuchsia.media.sounds",
    "//sdk/fidl/fuchsia.recovery",
    "//sdk/fidl/fuchsia.recovery.policy",
    "//sdk/fidl/fuchsia.sys",
    "//sdk/fidl/fuchsia.ui.brightness",
    "//sdk/fidl/fuchsia.ui.input",
    "//sdk/fidl/fuchsia.ui.policy",
    "//sdk/fidl/fuchsia.ui.scenic",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:unit",
    "//sdk/lib/ui/scenic/cpp",
    "//src/lib/fxl",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/ui/bin/root_presenter:color_transform",
    "//src/ui/bin/root_presenter:displays",
    "//src/ui/bin/root_presenter:factory_reset_manager",
    "//src/ui/bin/root_presenter:lib",
    "//src/ui/bin/root_presenter:media_buttons_handler",
    "//src/ui/bin/root_presenter:safe_presenter",
    "//src/ui/bin/root_presenter/tests/fakes",
    "//src/ui/lib/key_util",
    "//src/ui/testing:mock_input_device",
    "//third_party/googletest:gmock",
  ]
}

executable("root_presenter_apptests") {
  testonly = true

  sources = [
    "accessibility_focuser_registry_test.cc",
    "accessibility_pointer_event_registry_test.cc",
  ]

  deps = [
    "//garnet/public/lib/gtest",
    "//sdk/fidl/fuchsia.ui.input.accessibility",
    "//sdk/fidl/fuchsia.ui.policy.accessibility",
    "//sdk/lib/fidl/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:integration",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/ui/bin/root_presenter:lib",
    "//src/ui/bin/root_presenter/tests/fakes",
  ]
}