zircon/system/ulib/fidl-async/test/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/fidl/fidl.gni")
import("//build/fuzzing/fuzzer.gni")

test("fidl-async-test") {
  if (is_fuchsia) {
    fdio_config = [ "//build/config/fuchsia:fdio_config" ]
    if (configs + fdio_config - fdio_config != configs) {
      configs -= fdio_config
    }
  }
  sources = [ "llcpp_bind_test.cc" ]
  deps = [
    ":fidl.test.simple_llcpp",
    "//sdk/lib/fdio",
    "//zircon/system/ulib/async:async-cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/fidl-async:fidl-async-cpp",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/zxtest",
  ]

  # TODO(fxbug.dev/69585): This target uses raw zx::channel with LLCPP which is deprecated.
  # Please migrate to typed channel APIs (fidl::ClientEnd<T>, fidl::ServerEnd<T>).
  # See linked bug for details.
  configs += [ "//build/cpp:fidl-llcpp-deprecated-raw-channels" ]
}

fidl("fidl.test.simple") {
  sources = [ "simple.test.fidl" ]
}

fuchsia_unittest_package("fidl-async-test-pkg") {
  package_name = "fidl-async-test"
  deps = [ ":fidl-async-test" ]
}

group("tests") {
  testonly = true
  deps = [ ":fidl-async-test-pkg" ]
}