src/sys/component_manager/tests/routing/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_test.gni")
import("//build/test/test_package.gni")

group("tests") {
  testonly = true

  deps = [ ":routing_integration_test" ]
}

rustc_test("routing_integration_test_bin") {
  name = "routing_integration_test"
  edition = "2018"
  source_root = "integration_test.rs"
  deps = [
    "//sdk/fidl/fuchsia.component:fuchsia.component-rustc",
    "//sdk/fidl/fuchsia.io:fuchsia.io-rustc",
    "//sdk/fidl/fuchsia.sys2:fuchsia.sys2-rustc",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/sys/component_manager/tests/fidl:components-rustc",
  ]

  sources = [ "integration_test.rs" ]
}

test_package("routing_integration_test") {
  deps = [
    ":routing_integration_test_bin",
    "//examples/components/routing/echo_server",
    "//src/sys/component_manager/tests:trigger_bin",
  ]

  meta = [
    {
      path = rebase_path(
              "//examples/components/routing/echo_server/meta/echo_server.cml")
      dest = "echo_server.cm"
    },
    {
      path = rebase_path("meta/trigger.cml")
      dest = "trigger.cm"
    },
  ]

  binaries = [
    {
      name = "echo_server"
    },
    {
      name = "trigger"
    },
  ]

  v2_tests = [
    {
      name = "routing_integration_test"
    },
  ]
}