src/modular/bin/sessionmgr/story_runner/BUILD.gn

# Copyright 2016 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

source_set("story_runner") {
  sources = [
    "annotation_controller_impl.cc",
    "annotation_controller_impl.h",
    "module_context_impl.cc",
    "module_context_impl.h",
    "module_controller_impl.cc",
    "module_controller_impl.h",
    "ongoing_activity_impl.cc",
    "ongoing_activity_impl.h",
    "story_controller_impl.cc",
    "story_controller_impl.h",
    "story_provider_impl.cc",
    "story_provider_impl.h",
    "story_shell_context_impl.cc",
    "story_shell_context_impl.h",
  ]

  public_deps = [
    "//garnet/public/lib/fostr/fidl/fuchsia.modular",
    "//sdk/fidl/fuchsia.element",
    "//sdk/fidl/fuchsia.modular",
    "//sdk/fidl/fuchsia.modular.internal",
    "//sdk/fidl/fuchsia.ui.policy",
    "//sdk/fidl/fuchsia.ui.views",
    "//sdk/lib/fidl/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/inspect/cpp",
    "//src/modular/bin/basemgr/cobalt",
    "//src/modular/bin/sessionmgr:component_context",
    "//src/modular/bin/sessionmgr/agent_runner",
    "//src/modular/bin/sessionmgr/puppet_master/command_runners/operation_calls:add_mod_call",
    "//src/modular/bin/sessionmgr/storage:encode_module_path",
    "//src/modular/lib/async/cpp:future",
    "//src/modular/lib/async/cpp:operation",
    "//src/modular/lib/common:async_holder",
    "//src/modular/lib/common:teardown",
    "//src/modular/lib/deprecated_service_provider",
    "//src/modular/lib/fidl:app_client",
    "//src/modular/lib/fidl:array_to_string",
    "//src/modular/lib/fidl:environment",
    "//src/modular/lib/fidl:json_xdr",
    "//src/modular/lib/fidl:proxy",
    "//src/modular/lib/string_escape",
  ]

  deps = [
    "//sdk/fidl/fuchsia.ui.app",
    "//sdk/fidl/fuchsia.ui.scenic",
    "//sdk/lib/ui/scenic/cpp",
    "//src/lib/fsl",
    "//src/lib/uuid",
    "//src/modular/bin/sessionmgr/storage",
    "//src/modular/lib/fidl:clone",
    "//src/modular/lib/modular_config",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

executable("dev_story_shell_bin") {
  output_name = "dev_story_shell"
  sources = [ "dev_story_shell.cc" ]
  deps = [
    "//sdk/fidl/fuchsia.modular",
    "//sdk/fidl/fuchsia.ui.scenic",
    "//sdk/fidl/fuchsia.ui.views",
    "//sdk/lib/sys/cpp",
    "//src/modular/lib/app_driver/cpp",
    "//src/modular/lib/fidl:single_service_app",
    "//src/modular/lib/fidl:view_host",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

fuchsia_package_with_single_component("dev_story_shell") {
  manifest = "meta/dev_story_shell.cmx"
  deps = [ ":dev_story_shell_bin" ]
}

executable("annotation_controller_impl_unittest") {
  testonly = true

  sources = [ "annotation_controller_impl_unittest.cc" ]

  deps = [
    ":story_runner",
    "//src/lib/fxl/test:gtest_main",
    "//src/modular/bin/sessionmgr:annotations",
    "//src/modular/bin/sessionmgr/testing:annotations_matchers",
    "//src/modular/lib/testing:test_with_session_storage",
    "//third_party/googletest:gmock",
    "//third_party/googletest:gtest",
  ]
}

fuchsia_unittest_component("annotation-controller-impl-unittest") {
  deps = [ ":annotation_controller_impl_unittest" ]
}

executable("story_controller_impl_unittest") {
  testonly = true

  sources = [ "story_controller_impl_unittest.cc" ]

  deps = [
    ":story_runner",
    "//src/lib/fsl",
    "//src/lib/fxl/test:gtest_main",
    "//src/modular/lib/fidl:clone",
  ]
}

fuchsia_unittest_component("story-controller-impl-unittest") {
  deps = [ ":story_controller_impl_unittest" ]
}

fuchsia_test_package("story_runner_unittests") {
  test_components = [
    ":annotation-controller-impl-unittest",
    ":story-controller-impl-unittest",
  ]
}