src/ui/a11y/bin/a11y_manager/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")

package("a11y_manager") {
  deps = [
    ":bin",
    "//src/ui/a11y/lib/screen_reader/i18n:resources",
  ]

  binaries = [
    {
      name = "a11y_manager"
    },
  ]

  meta = [
    {
      path = rebase_path("meta/a11y_manager.cmx")
      dest = "a11y_manager.cmx"
    },
    {
      path = rebase_path("meta/a11y_manager.cml")
      dest = "a11y_manager.cm"
    },
  ]

  resources = [
    # Needed to load Screen Reader strings.
    {
      path = rebase_path(
              "$target_gen_dir/../../lib/screen_reader/i18n/en/l10n.json")
      dest = "assets/locales/en/l10n.json"
    },

    # [START icudata_resource]
    {
      # Fuchsia's ICU does not have libicudata.so, and the locale data MUST
      # be loaded from a file instead.
      path = rebase_path("//third_party/icu/common/icudtl.dat")
      dest = "icudtl.dat"
    },
  ]
}

executable("bin") {
  output_name = "a11y_manager"

  sources = [ "main.cc" ]

  deps = [
    ":lib",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/syslog/cpp",
    "//src/ui/a11y/lib/annotation",
    "//src/ui/a11y/lib/view",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/trace-provider:trace-provider-with-fdio",
  ]

  include_dirs = [ "//third_party/glm" ]
}

source_set("lib") {
  sources = [
    "app.cc",
    "app.h",
  ]

  public_deps = [
    "//sdk/fidl/fuchsia.accessibility",
    "//sdk/fidl/fuchsia.accessibility.gesture",
    "//sdk/fidl/fuchsia.accessibility.semantics",
    "//sdk/fidl/fuchsia.accessibility.tts",
    "//sdk/fidl/fuchsia.intl",
    "//sdk/fidl/fuchsia.math",
    "//sdk/fidl/fuchsia.settings",
    "//sdk/fidl/fuchsia.ui.input.accessibility",
    "//sdk/fidl/fuchsia.ui.views.accessibility",
    "//src/ui/a11y/lib",
  ]

  deps = [
    "//sdk/fidl/fuchsia.ui.gfx",
    "//sdk/fidl/fuchsia.ui.input",
    "//sdk/fidl/fuchsia.ui.views",
    "//sdk/lib/fidl/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fsl",
    "//src/lib/fxl",
  ]
}